通过userform中的textbox控件进行VBA循环
通过userform中的textbox控件进行VBA循环
提问于 2018-08-08 15:20:00
我看过许多关于循环遍历UserForm控件的帖子，但似乎无法根据我的需要调整我找到的代码，需要帮助。
我正试图找出这样的情景：
- 我在一个用户表单上有44个文本框，其名称都以"ch“示例"chTextBox1”开头
- 当用户表单激活时，我需要循环遍历以"ch“开头的所有文本框，并根据单元格的内部颜色将这些文本框的背景色更改为颜色。
下面是我一直在处理的代码，我要么在无限循环中结束，要么我得到
错误424
Private Sub UserForm_Activate()
Dim wb As Workbook
Dim wsRR As Worksheet
Dim bColor As Range
Dim c As Control
Dim y As String
Set wb = Application.ThisWorkbook
Set wsRR = wb.Sheets("RiskRating")
Set bColor = wsRR.Range("C3")
For Each c In JHKey.Controls
If TypeName(c) = "TextBox" Then
y = Left(c, 2)
End If
If y = "ch" Then
c.BackColor = bColor.Interior.Color
End If
Next c
End Sub回答 1
Stack Overflow用户
回答已采纳
发布于 2018-08-08 16:05:33
尝试将If语句测试"ch“放在If语句测试"TextBox”中。此外，在检查控件名称时，应指定控件的name属性，否则该属性默认为其Value属性。另外，顺便提一下，我建议用关键字Me代替JHKey，它指的是用户名本身，而不管它的名称如何。
Private Sub UserForm_Activate()
Dim wb As Workbook
Dim wsRR As Worksheet
Dim bColor As Range
Dim c As Control
Dim y As String
Set wb = Application.ThisWorkbook
Set wsRR = wb.Sheets("RiskRating")
Set bColor = wsRR.Range("C3")
For Each c In Me.Controls
If TypeName(c) = "TextBox" Then
y = Left(c.Name, 2)
If y = "ch" Then
c.BackColor = bColor.Interior.Color
End If
End If
Next c
End Sub页面原文内容由Stack Overflow提供。腾讯云小微IT领域专用引擎提供翻译支持
原文链接：
https://stackoverflow.com/questions/51750281
复制相关文章
相似问题
腾讯云开发者
Copyright © 2013 - 2026 Tencent Cloud. All Rights Reserved. 腾讯云 版权所有
深圳市腾讯计算机系统有限公司 ICP备案/许可证号：粤B2-20090059 
粤公网安备44030502008569号
腾讯云计算（北京）有限责任公司 京ICP证150476号 | 京ICP备11018762号