问[kdb+/q]：将邻接矩阵转换为邻接表

EN

您有错误，因为原始Q成语是用k2编写的--这是现代kdb+版本不支持的k的旧版本。当前版本的k是k4，它与k2不向后兼容。

例如，X _vs Y (X和Y是旧k2中的整数原子或列表，行为类似于X vs Y )将从3.4t 2015.12.13：http://code.kx.com/q/ref/lists/#vs开始在kdb+中运行

自3.4t 2015.12.13:对于整数类型，计算Y的基表示形式为radices。

另一个例子。的确，^ in k2是一个形状运算符，但它已经不再是了。在k2中，^m将从示例中返回矩阵m的2 3，而据我所知，当前实现的行为类似于q的not null。

现在，回到原来的问题，“如何用q语言构造邻接列表”。这样做的方法之一是：

q)lm:{flip raze(til count x),''where each x}

或

k)lm:{+,/(!#x),''&:'x}

更新：下面是它的工作原理。如果我们使用任何“冗长”的语言构建一个邻接列表，我们就会这样做：

for i = 0 to <number of rows> - 1            <---- (1)
    for j = 0 to <number of columns> - 1     <---- (2)
        if M[i;j] <> 0                       <---- (3)
            print i, j

在像Q这样的数组语言中，可以将(1)“转换”为til count M，因为count将返回顶层的元素数，即行数。(2)和(3)的组合可以用where each M表示。实际上，对于每一行，我们返回非零元素的位置。给定一个原始矩阵m，我们将得到：

til count m -> 0 1
where each m -> (0 2; 0 2)

我们所需要做的就是连接行和列索引。我们不能只使用,'，因为它将将0与第一个0 2连接起来，而1将与第二个0 2连接，从而导致(0 0 2; 1 0 2)。我们需要进行一个更深的层次，将左边的每个元素与右侧嵌套列表(0 2; 0 2)的每个元素的每个元素连接起来，因此在,''中使用双撇号。

我希望现在说得通了。

就我个人而言，我不会使用flip (或k中的+ )，我无法读取这种形式的邻接矩阵：

0 0 1 1
0 2 0 2

我认为这是更易读的：

0 0
0 2
1 0
1 2

但当然要看你自己了。